In the last few weeks (months?), I have been wasting more time on endless
and unproductive political discussions about the ownership, availability,
maintenance and future of LISTSERV than I normally used to spend on the
code itself, back in the days of political peace. I am getting seriously
fed up with this whole business, and have therefore decided to start a
survey on this topic. It is rather like a kind of referendum, as I plan
to act according to the results (within reason).
The survey is open to anybody who knows what "LISTSERV" stands for,
although the results will be split into several sub-groups (EARN vs
non-EARN, maintainers vs users, etc). Feel free to forward this note to
anybody who might be interested.
To answer the survey, you must obtain a copy of 'SURV1 EXEC'. If you have
access to a VM system, all you have to do is to run the exec (after
checking that it does not propagate a Christmas tree all over the network
:-) ). If you do not have any VM account, please refer to the
instructions at the beginning of the exec (basically you will have to
extract the questions from the 'data' section of the exec and mail your
replies to me; I will then enter them into the database).
SURV1 EXEC will be mailed to the LSTSRV-L list (I expect that all the
people subscribed to LSTSRV-L will want to answer the survey); other
people can obtain a copy from LISTSERV@LEPICS by sending a 'GET SURV1
EXEC' command (ie TELL LISTSERV AT LEPICS GET SURV1 EXEC). Please do NOT
AFD or FUI to it; the exec will be destroyed when the survey is closed
(the deadline for answering is 18-Feb-89).
>>> PLEASE read the questions carefully and answer seriously, this is an
>>> important survey that can dramatically influence the future of
>>> LISTSERV. If you do not have enough time to devote to it, I would
>>> rather that you did not answer at all.
Thanks and regards, Eric
/* Standard LISTSERV-based survey exec
This program will only work on a BITNET/EARN/NetNorth site running VM (I
do not have time to write one for each operating system on the network).
If you cannot run it, please extract the text of the questions from the
data following the line marked 'Survey_Data:' below and "manually" reply
to them. I will then run the program for you to enter your answers in the
database.
*/
Address 'COMMAND'
Do read = 1
If Word(Sourceline(read),1) == 'Survey_Data:' Then Leave
End
count = 0
output. = ''
Do read = read+1
line = Sourceline(read)
If Left(line,1) ^== '.' Then
Do
Say line
Iterate
End
Parse var line '.'cmd line
Upper cmd
If cmd == 'DONE' Then Leave
If cmd == '*' Then Iterate
Interpret 'Call CMD_'cmd
End
fileid = 'SURVEY CMSUT1 A1'
'ERASE' fileid
write = 'EXECIO 1 DISKW' fileid '0 (STRING'
write '/SURVEY ANSWER' survey#
write '//Data DD *,EOF'
Do i = 1 for count
write output.i
End
'FINIS' fileid
Say
'DMSDDL SEND' fileid 'TO' destination '(NOLOG NOACK'
'ERASE' fileid
Exit 0
CMD_TO:
destination = line
Return
CMD_ID:
survey# = line
Return
CMD_CLEAR:
'VMFCLEAR'
Return
CMD_PAUSE:
Say
Say Centre('>>> Press ENTER to continue <<<',73)
Parse upper pull reply .
If reply == 'QUIT' Then Signal Quit
'VMFCLEAR'
Return
CMD_LABEL:
Return
CMD_IF:
Parse upper var line boolean ' THEN ' where .
Interpret 'boolean =' boolean
If boolean == 0 Then Return
Do read = read+1
Parse upper Value Sourceline(read) with cmd label .
If cmd == '.LABEL' & label == where Then Return
End
CMD_UNTIL:
line = Strip(line)
If Substr(Date('S'),3) ^> line Then Return
Parse var line yy +2 mm +2 dd +2
Say 'Sorry, this survey has been closed as of' yy'/'mm'/'dd'.'
Exit 28
CMD_CE:
Say Centre(Strip(line),73)
Return
CMD_ASK:
count = count+1
keepin = ''
opt = 0
Do forever
Parse upper var line w .
Select
When w == 'IF' Then
Do
Parse var line . boolean line
Interpret 'boolean =' boolean
If boolean ^== 1 Then Return
End
When w == 'KEEPIN' Then Parse var line . keepin line
When Abbrev('OPTIONAL',w,3) Then Parse Value 1 line with opt . line
Otherwise Leave
End
End
Parse var line type line
If opt Then
Say '-> Just press ENTER if you do not wish to answer this question.'
Do forever
Parse pull reply
reply = Space(reply)
If Translate(reply) == 'QUIT' Then Signal Quit
If opt & reply == '' Then Return
Interpret 'Call TYPE_'type line
If result ^== 0 Then Iterate
If keepin ^== '' Then Interpret keepin '=' reply
output.count = reply
Return
End
TYPE_YESNO:
Upper reply
Select
When Abbrev('YES',reply,1) Then reply = 1
When Abbrev('NO',reply,1) Then reply = 0
Otherwise
Say 'Please answer YES or NO:'
Return 1
End
Return 0
TYPE_NUM:
Parse var line a b .
If ^Datatype(reply,'W') | reply < a | reply > b Then
Do
Say 'Please enter an integer number from' a 'to' b':'
Return 1
End
Return 0
TYPE_DEC:
Parse var line a b .
If ^Datatype(reply,'N') | reply < a | reply > b Then
Do
Say 'Please enter a decimal number from' a 'to' b':'
Return 1
End
Return 0
Quit:
Parse source . . myname .
Say 'Survey cancelled, no data has been sent. Type' myname,
'to restart survey.'
Exit 100
/* Insert survey data below
Survey_Data:
.until 890218
.clear
Because of the political turmoil surrounding the issue of LISTSERV
development, maintenance and support, the time has come when I must again
ask YOUR opinion of what should be done with LISTSERV in the future.
Everybody who has been in touch with LISTSERV is invited to answer this
survey, LISTSERV maintainers and LISTSERV users alike, be they on BITNET,
EARN, NetNorth, ARPAnet, etc. Only statistics will be published - the
privacy of individual answers is guaranteed, although you should know
that, to prevent people from answering several times, the database server
will keep a list of all the persons who have answered the survey. This
list can be accessed only by the LEPICS computing centre staff.
Most questions are optional, so that you do not have to answer if you
feel that you do not have enough experience with or knowledge of the
product to provide a valuable answer.
Finally, you can quit the survey at any time by replying "QUIT" to any
question. Your answers will then be discarded and nothing will be added
to the database.
.pause
.ce *** Preliminary questions ***
Are you an EARN user (here 'EARN' really means 'just EARN', ie you should
answer NO if you are a BITNET or NetNorth user)? (YES|NO):
.ask keepin earn yesno
Are you a LISTSERV maintainer ("postmaster")? (YES|NO):
.ask keepin postmaster yesno
.clear
.ce *** The present of LISTSERV ***
You will now be asked to express your satisfaction about the various
services that LISTSERV is providing TODAY. Please answer in a 0-5 scale,
where 0 means "Extremely unsatisfactory" and 5 is "Extremely
satisfactory".
.if ^postmaster then post1
As a LISTSERV maintainer, please try to keep performance in mind all
throughout this survey!
.label post1
How do you rate the service provided by LISTSERV to the user community,
as a whole (remember: 0 = very bad, 5 = very good)?
.ask num 0 5
How do you rate the ease-of-use of these services (ie 0 = impossible to
use without special training, 5 = extremely easy to use)?
.ask num 0 5
How do you rate the quality of the maintenance (difficulty to get a bug
report accepted, time to get a fix, quality of the fix, etc)? (0-5):
.ask opt num 0 5
.if earn then earn1
How do you rate the quality of the support provided by the author (time
to get a question answered, accuracy of the answer, etc)? (0-5):
.label earn1
.ask if ^earn opt num 0 5
.clear
.ce *** The future of LISTSERV ***
You will be asked several times throughout this survey to give your own
opinion on the desireability of a change to LISTSERV. Please use the
following scale when answering:
0 - Extremely undesirable, consequences would be catastrophic for us!
1 - Undesirable, should be avoided if possible.
2 - Tolerable, even though we would rather avoid it.
3 - Neutral.
4 - Desirable, we would like to see this done.
5 - Extremely desirable, this is definitely the way to go.
Remember: <3 = Don't do it, 3 = Neutral, >3 = Do it.
.pause
.ce *** LISTSERV as commercial, vendor-maintained software? ***
In this section, you will be asked your opinion on the consequences of
LISTSERV becoming a commercial, vendor-developed and vendor-maintained
piece of software. It is assumed that the license cost is reasonable, and
that the vendor in question is a serious company. Development and
maintenance would be done by an employee of the company, not by me.
---------
First of all, how desirable do you think this solution would be, all
things considered? (0-5):
.ask opt num 0 5
Do you think the quality of the software itself would improve? Please
reply -5 ("It would become completely useless") to 5 ("It would become
really more useful"):
.ask opt num -5 5
Do you think the quality of the maintenance would improve? (-5 to 5):
.ask opt num -5 5
Would you trust the vendor to develop and improve the software in a way
that meets your needs? (YES|NO):
.ask opt yesno
.clear
Now let's assume that the vendor only packages and sells the software,
while I keep doing the development and maintenance. The vendor guarantees
that if I am forced to stop working on LISTSERV, one of their employees
will continue my work.
How desirable do you think this solution would be, then? (0-5):
Remember: <3 = Don't do it, 3 = Neutral, >3 = Do it.
.ask opt num 0 5
Do you think the quality of the software itself would improve in
that case? (-5 to 5):
.ask opt num -5 5
Do you think the quality of the maintenance would improve? (-5 to 5):
.ask opt num -5 5
Would you then trust the vendor and myself to develop and improve the
software in a way that meets your needs? Do not forget to take into
account the fact that the vendor might impose some requirements on me,
like a different ordering of the "wish list" than I would have chosen
myself. (YES|NO):
.ask opt yesno
.clear
.ce *** LISTSERV as an EARN-owned, EARN-maintained service? ***
In this section, you will be asked your opinion on the consequences of
LISTSERV becoming the property of EARN, with maintenance being done by an
employee of EARN (EARN now has a budget to hire the equivalent of 4
full-time "people", 2 of which being dedicated to the maintenance and
operation of the network). It is assumed that EARN would grant BITNET and
NetNorth the right to use the software at no cost to your institution;
however permission to distribute changes to the software would be the
prerogative of EARN, in order to avoid having dozens of different
versions of LISTSERV running on the network. That is, EARN would keep
control of the software.
First of all, how desirable do you think this solution would be, all
things considered? (0-5):
.ask opt num 0 5
Assuming that the EARN employee in charge of development and maintenance
is not me, do you think the quality of the software itself would improve?
Please reply -5 ("It would become completely useless") to 5 ("It would
become really more useful"):
.ask opt num -5 5
Still assuming it is not done by me, do you think the quality of the
maintenance would improve? (-5 to 5):
.ask opt num -5 5
Would you trust EARN to develop and improve the software in a way that
meets your needs? (YES|NO):
.ask opt yesno
.clear
Now let's assume that LISTSERV becomes the property of EARN but I keep
doing the maintenance and development. EARN guarantees that if I am
forced to stop working on LISTSERV, one of their employees will continue
my work.
How desirable do you think this solution would be, then (0-5):?
.ask opt num 0 5
Do you think the quality of the software itself would improve in
that case? (-5 to 5):
.ask opt num -5 5
Do you think the quality of the maintenance would improve? (-5 to 5):
.ask opt num -5 5
Would you then trust EARN and myself to develop and improve the software
in a way that meets your needs? Do not forget to take into account the
fact that EARN might impose constraints on me, eg migration of the
software to OSI protocol. (YES|NO):
.ask opt yesno
.clear
.ce *** LISTSERV as a BITNET-owned, BITNET-maintained service? ***
In this section, you will be asked your opinion on the consequences of
LISTSERV becoming the property of BITNET, with maintenance being done by
a pool of properly selected and knowledgeable BITNET volunteers (I would
not be part of that pool, although I would provide some guidance at the
beginning). The BITNET BoT would guarantee that, in the case that the
BITNET volunteers can no longer keep working on LISTSERV, they would hire
someone to continue this work (probably as part of the BITNIC staff). It
is further assumed that BITNET would EARN and NetNorth the right to use
the software at no cost.
First of all, how desirable do you think this solution would be, all
things considered? (0-5):
.ask opt num 0 5
Do you think the quality of the software itself would improve? Please
reply -5 ("It would become completely useless") to 5 ("It would become
really more useful"):
.ask opt num -5 5
Do you think the quality of the maintenance would improve? (-5 to 5):
.ask opt num -5 5
Would you trust BITNET to develop and improve the software in a way that
meets your needs? Please note that BITNET is almost free from politics,
and that there would probably be little or no constraint placed on the
pool of volunteers. (YES|NO):
.ask opt yesno
.clear
All things considered, what do you think is the best option for the
future of LISTSERV?
1 - Keep it the way it is today.
2 - Sell it to EARN.
3 - Sell or donate it to BITNET.
4 - Make it into a commercial, vendor-supported product.
.ask opt num 1 4
.clear
.ce *** Putting a price tag to LISTSERV ***
In the event that LISTSERV had to be sold, the issue of "what is the
financial value of LISTSERV" will undoubtedly come up. Actually this
issue is likely to come up anyway, regardless of whether I decide to sell
it or not. I will therefore ask you a few questions along these lines, to
which I would like you not to reply if you are not sure that you have
enough information to provide a "valid" reply.
In the event that LISTSERV became a commercial product, or that it
otherwise became the property of an entity asking your site for money
(directly or through your EARN/BITNET/NetNorth membership fee) in order
to run it, how much do you think your institution would be willing to pay
for a "One Time Charge" license? Please answer with the amount, in
thousands of US dollars, that your site would be willing to pay; do not
put a '$' sign in your reply, or a 'k' at the end to indicate thousands.
For example, for $5500, you would reply '5.5'. Reply '0' if your site
would never accept to pay anything to run LISTSERV.
>>> Please do NOT answer if you do not have good reasons to think that
>>> your answer would be accurate!
.ask opt dec 0 999
.clear
Let's assume that your institution had to re-create LISTSERV from
scratch, ie write a piece of software that does exactly the same thing as
LISTSERV, running in the same environment and with comparable
performance.
The person doing this would not be allowed to extract pieces of code from
the existing version of LISTSERV, or even to look at the code to see how
things are done, BUT he/she would be provided with a complete functional
description of what LISTSERV does.
What type of programmer would you choose to do this work, if you were the
manager of the organization having to do the work (knowing, of course,
that the salary is not the same):
1 - Novice, straight out of grad school.
2 - Beginner, 1-2 year of experience with VM, knows REXX, not assembler.
3 - Knowledgeable, 2-4 years of VM experience, good knowledge of REXX,
can understand assembler but finds it hard to program in assembler.
4 - Expert, 5+ years of experience, REXX expert, can understand and write
good assembler.
5 - Wizard, remembers his first IPL of CP-40, knows the opcodes and card
punch codes of any assembler instruction you can name, etc.
.ask opt num 1 5
.clear
How long do you think it would take this person to do the work (this
includes testing, debugging, etc), in months?
.ask opt dec 0 999
How much do you think this would cost your institution (counting not only
the salary paid to this person but also the corresponding taxes/welfare
paid to the state, the CPU time and disk space he would use, the floor
space for his office/terminal, and all other associated overhead)? Please
answer with the amount in thousands of US dollars (no '$', no 'k' in the
answer):
.ask opt dec 0 999
How much do you think it would cost your institution, in thousands of US
dollars per month, to maintain the software (ie write bug fixes and
develop improvements that become required by a change in the technology
or protocols use in the network)?
.ask opt dec 0 99
.*
.* End of questions
.*
.clear
Thank you for having answered this survey. Your answers are being sent to
LISTSERV@LEPICS for inclusion in the database.
.to LISTSERV AT LEPICS
.id 1
.done
*/
|
